HiFiDuino – Changes to Display Code

To control my Buffalo III-SE DAC, I use the source code and setup from hifiduino.wordpress.com.  I’ve noticed, however, that my display (a NewHaven OLED) appears to “flicker” because the sample rate and input source are updated every few seconds, even when they haven’t changed.  I made a few edits to the code so that the display will only be changed when the sample rate or input source changes.

First, I defined some new constants:

//Define constants used to identify incoming signal types 
#define NOLOCK -1 //constant used to identify that there is no lock on the incoming signal
#define SPDIF 1 //constant used to identify incoming signal as SPDIF
#define DSD 2 //constant used to identify incoming signal as DSD
#define PCM 3 //constant used to identify incoming signal as PCM

Then, some new variables:

unsigned long displayedSR = 0; // Holds the value of the last sample rate we received and are displaying
unsigned int displayedSigType = 0; // Holds the value of the signal type that is currently being displayed
boolean refreshDisplay = false; // Value that we will query to determine if we should update the display's sample rate

Then I created a new function to handle printing the sample rate and input source (not really necessary, but I find the code below easier to understand):

void printSampleRate(int sigType, long sampleRt) {
  //First, print out the signal type  
  lcd.setCursor(8,0);  //set the cursor to the start of the signal type character area
  if (sigType == NOLOCK) {  //No lock, but we should still show the input the user selected
    if(spdifIn) {  // spdifIn=true means we selected SDPIF input
      lcd.print("SP");  
    } else {  // Otherwise, we selected Serial Interface as input
      lcd.print("SE");
    }
    lcd.write(127);            // Print arrow to indicate it is input selection rather than an actual input      
  } else if (sigType == SPDIF) {  //We have a lock on a SPDIF signal
    lcd.print("SPd  ");    
  } else if (sigType == DSD) {    //We have a lock on a DSD signal
    lcd.print("DSD  ");
  } else {			   //If it's not SPDIF or DSD, it must be PCM
    lcd.print("PCM  ");    
  } 
  
  //Now, print out the sample rate
  lcd.setCursor(12,0);         	//Set the cursor to the start position of the sample rate characters
  lcd.print("        ");	//Clear the old sample rate reading
  lcd.setCursor(12,0);		//Go back to the sample rate character start position   
  
  if (sigType == NOLOCK) {		 //Update the display to show that we don't have a lock
    lcd.print(" No Lock");
  } else if(SRExact==true) {		 //We're going to display the exact sample rate 
    if (sigType != DSD) lcd.print(" ");  //Add a space before any non-DSD sample rate
    lcd.print(sampleRt, DEC);            //Print sample rate in exact format
  } else {				 //Print out nominal sample rates
    if(sigType == DSD){      // Print nominal DSD sample rates
      if(sampleRt>6143000) {
        lcd.print("6.1 MHz");
      } else if(sampleRt>5644000) {
        lcd.print("5.6 MHz");
      } else if(sampleRt>3071000) {
        lcd.print("3.0 MHz");
      } else if(sampleRt>2822000) {
        lcd.print("2.8 MHz");
      } else {
        lcd.print("UNKNOWN");
      }
    } else {  // If not DSD then it is I2S or SPDIF
      if(sampleRt>383900) {
        lcd.print("384 KHz");
      } else if(sampleRt>352700) {
        lcd.print("352 KHz");
      } else if(sampleRt>191900) {
        lcd.print("192 KHz");
      } else if(sampleRt>176300) {
        lcd.print("176 KHz");
      } else if(sampleRt>95900) {
        lcd.print(" 96 KHz");
      } else if(sampleRt>88100) {
        lcd.print(" 88 KHz");
      } else if(sampleRt>47900) {
        lcd.print(" 48 KHz");
      } else { 
        lcd.print(" 44 KHz");
      }        
    } //End of I2S/SPDIF nominal block    
 } //End of nominal sample rate block
} //End of printSampleRate function

I changed the first portion of the loop() function as follows:

  if(((millis() - displayMillis > INTERVAL_SAMPLE*1000)&&!selectMode) || refreshDisplay) {  //check to see if it's time to refresh the sample rate
    
    displayMillis = millis(); // Saving last time we displayed sample rate
    Status=readRegister(27);  // Read status register to see if we've got a lock on the signal
    int signalType = -1;      // Variable we will use to identify what type of signal we're receiving - set to undefined value until we have a signal 

    if (Status&B00000001) {   // Locked onto the signal, so determine whether we need to update display
    	sr=sampleRate();      // Get the sample rate from register
	//Determine what type of signal we are receiving
    	SPDIFValid = false;
        if (Status&B00000100) {
    	   signalType=SPDIF;
           SPDIFValid = true; 			// Incoming signal is valid SPDIF
    	} else if (Status&B00001000) {
    	   signalType=DSD;  			// Incoming signal is DSD
    	   sr*=64;				// For DSD, the sample rate is 64x
    	} else {
    	   signalType=PCM;			// If we have a lock and the incoming signal is not SPDIF or DSD, it must be PCM
      	}  // End of "lock signal" if statement
    } else {                                    // We can't lock onto the incoming signal
      signalType = NOLOCK;                      // Set our signal type to indicate that there is no lock
      sr = -1;                                  // Because we can't lock onto the signal, we can't figure out the appopriate sample rate - set to -1 (undefined)
    }  // End of "no lock" else statement
    
    if ((displayedSR != sr) || (displayedSigType != signalType) || refreshDisplay) {	//If the sample rate we were displaying does not match the current sample rate
                                                                                        //or if the signal type has changed, we need to update the display   
       printSampleRate(signalType, sr);         // Call the printSampleRate function and pass in the signal type and the sample rate
       displayedSR = sr;			// We've updated the displayed sample rate, so set the displayed sample rate variable to match
       displayedSigType = signalType;           // We've also updated the displayed signal type, so set the corresponding variable
       refreshDisplay = false;                  // We've refreshed the display, so we won't need to do this again until something changes
    } // End of "refresh display" if statement

  // Print out "heartbeat" to show that the software is still running...
    lcd.setCursor(0,1);
    if(pulse++%2)lcd.write(0xDE);  // Print a "pulse" to indicate the controller is working
    else lcd.write(0xEB);
  }

Finally, I added a line to the last “if” statement in the loop function, setting the refreshDisplay boolean equal to true:

 // When the being-in-select mode timer expires, we revert to volume/display mode
  if(selectMode&&millis()-selectMillis > INTERVAL_SELECT*1000){
    selectMode=false;  // No longer in select mode
    printSelectBar(A); // "Removes" the select bar by printing blanks
    select=VOL;        // Back to volume mode
    writeSettings();   // Write new settings into EEPROM, including current input
    refreshDisplay = true;  //We've left "menu" mode, so we need to update the sample rate and signal type
  }

Currently, I only have SPDIF inputs connected to my DAC, so I would appreciate people pointing out any bugs or issues they might encounter with the changes above.